---

Palettázó berendezés beüzemelése és mûködtetése

SPC200- PLC összekötése | SPC200 programozás | PLC program

 

A tanszéken lévõ palettázó berendezés (24. ábra) egy olyan szervopneumatikus manipulációs rendszer, amely azonos méretû és típusú munkadarabok, különféle lyuk osztású palettán történõ elrendezésére alkalmas.

24. ábra Szervopneumatikus palettázó berendezés

Három lineáris (X Y és Z), illetve opcionálisan egy rotációs C tengellyel rendelkezik. A nagy megbízhatóság és pontosság érdekében a lineáris tengelyek dugattyúrúd nélküli hengerek. A Z tengely egy pneumatikus lineáris modul, ami igazából egy olyan kompakt felépítésû pneumatikus végrehajtó elem, amely egyesíti a mozgatás (hagyományos felépítésû pneumatikus munkahenger); a löketállítás (belsõ véghelyzet-határoló ütközõkkel); a véghelyzet-csillapítás (progresszív karakterisztikájú, a csillapítási út mentén "felkeményedõ" hidraulikus lökéscsillapítók); és a helyzetérzékelés (kívülrõl is jól látható világító üzemállapot jelzõjû beépített Reed-relés érzékelõ) funkcióit. Az opcionális C tengely teszi lehetõvé a függõleges tengely menti forgatást, így az egyes paletták illetve rakományok orientációjának megváltoztatását. A Z ill. C tengelyen egy standard kétpontos pneumatikus megfogó található, mely nélkül a palettázó berendezés nem tudná ellátni anyagmozgatási feladatát.

Lap tetejére

SPC200- PLC fizikai összekötése

A palettázó berendezést Record Select üzemmódban használjuk, ezért a bekötése is ennek megfelelõ. A villamos tápegység modul bekötése az elõírt módon készült.

Az SPC 200 bekötése:

25. ábra SPC200 moduljai

Az FC 440-es PLC bekötése:

26. ábra SPC200 moduljai

További információ a részletes villamos bekötési segédletben.

Lap tetejére

 

SPC200 felprogramozása

Miután elvégeztük a megfelelõ bekötéseket, következhet az SCP és a PLC programozása. Mielõtt nekilátunk az SPC-n futó program megírásához, bizonyos beállításokat el kell végeznünk.
Meg kell adnunk a hardver tulajdonságait (27. ábra). Itt találjuk a Record Select mód kiválasztásának lehetõségét és az egyes tengelyekre jellemzõ paraméterek megadására szolgáló ablakokat. Ezen paraméterek beállítása, külön ezt a témát célzó szakdolgozat alapján történt. A Hardware feliratra kattintva egy egyszerû Upload funkcióval az SPC-n lévõ beállított paramétereket hozzáadhatjuk programjainkhoz. A Software feliratra kattintva, pedig az Insert Object funkcióval hozhatjuk létre konkrét programunkat, amely a berendezés mûködését fogja leírni.

27. ábra Hardware és Software elemei

Az SPC200 programjának sorai a palettán lévõ rakomány mozgatásához szükséges lépéseket írja le az alábbi parancsok felhasználásával [7.]:

G00	Pozícionálás a lehetõ legnagyobb sebességgel.
	Parancsszerkezet	Nn G00 [ G90 | G91 ] Xn | X@n
	Kötelezõ paraméterek	Xn – pozíció megadása [mm] (n=0…450), vagy X@n – pozíció regiszterszáma (n=0…99)
	Segédparaméterek	G90 – abszolút értékmegadás G91 – relatív értékmegadás
	Mûködés	A tengely a lehetõ legnagyobb sebességgel a jelenlegi pozícióról a megadott pozícióra mozog. A sebesség- és gyorsulásérték automatikusan a maximális értéket kapja. A mozgási mód aktív marad további változtatásig.

G01	Pozícionálás megadott sebességgel.
	Parancsszerkezet	Nn G01 [ G90 | G91 ] Xn | X@n FXn
	Kötelezõ paraméterek	Xn – pozíció megadása [mm] (n=0…450), vagy X@n – pozíció regiszterszáma (n=0…99) FXn – mozgás sebessége [%] ( a lehetõ legnagyobb sebességbõl számítva; 0=100%, 1=1%, 99=99%)
	Segédparaméterek	G90 – abszolút értékmegadás G91 – relatív értékmegadás
	Mûködés	A tengely a parancsban megadott sebességgel mozog a jelenlegi pozícióról a megadott pozícióra. A sebességet és a gyorsulást a program a lehetõ legnagyobb értékekbõl számítja ki. A mozgási mód aktív marad további változtatásig.

G90	Abszolút értékmegadás.
	Parancsszerkezet	Nn G90 Xn | X@n
	Kötelezõ paraméterek	Xn – pozíció megadása [mm] (n=0…450), vagy X@n – pozíció regiszterszáma (n=0…99)
	Mûködés	Az abszolút értékmegadáskor a beírt értékre mozog a tengely. Az abszolút értékmegadás további változtatásig megõrzõdik!

G91	Relatív értékmegadás.
	Parancsszerkezet	Nn G91 Xn | X@n
	Kötelezõ paraméterek	Xn – pozíció megadása [mm] (n=0…450), vagy X@n – pozíció regiszterszáma (n=0…99)
	Mûködés	A relatív értékmegadáskor a beírt érték a pillanatnyilag elfoglalt pozícióértékhez adódik hozzá és a mozgás ennek megfelelõen pozitív vagy negatív irányú, a beírt értékkel egyezõ nagyságú elmozdulás lesz. A relatív értékmegadás további változtatásig megõrzõdik!

#S	Egybites állomány beállítása.
	Parancsszerkezet	Nn #S<állomány>
	Kötelezõ paraméterek	<állomány> - a beállítani kívánt állomány jelölése
	Mûködés	A megadott állomány beállításra kerül. Ezen állomány lehet Flag (memória, F0…F63) vagy kimenet (a hardver konfigurációnak megfelelõen, szabadon programozható). A Flag-ek (memóriák) megtartják értéküket a következõ változtatásig.

#R	Egybites állomány visszaállítása.
	Parancsszerkezet	Nn #R<állomány>
	Kötelezõ paraméterek	<állomány> - a beállítani kívánt állomány jelölése
	Mûködés	A megadott állomány visszaállításra kerül. Ezen állomány lehet Flag (memória, F0…F63) vagy kimenet (a hardver konfigurációnak megfelelõen, szabadon programozható).

A mozgatást megvalósító program:

N000 G00 G90 X0 Y0
N001 G01 G91 X40 FX50
N002 G01 G91 Y40 FY50
N003 G01 G91 X-40 FX50
N004 G01 G91 Y-40 FY50
N005 #SQ2.4
N006 #RQ2.4
N007 #SQ2.5
N008 #RQ2.5
N009 #SQ2.0
N010 #RQ2.0
N011 #SQ2.1
N012 #RQ2.1
N013 #SQ2.3
N014 #RQ2.3

A palettán lévõ lyukak, amikbe a szállítandó elemek kerülnek, egymástól 40 mm-re helyezkednek el, ezért szerepel az egyes sorokban 40 mm-es relatív, pozitív és negatív irányú elmozdulási érték. Ezen elmozdulásokhoz, a pontosabb pozícionálás érdekében egy kisebb sebesség érték tartozik. A #S és #R parancsok segítségével konkrét kimeneteket (15. táblázat) állíthatunk be (Set, Reset). Egy NC rekordban csak egy ilyen utasítás szerepelhet, külön sorban kell minden egyes Set és Reset parancsot megírni, ellenkezõ esetben „hibás szintaktika” üzenetet kapunk.
Record Select módban ezen NC rekord sorokat és azok parancsait hívhatjuk életre a magasabb rendu PLC segítségével annak megfeleloen, hogy milyen bináris kódot küld az SPC200 számára.
Ennél a feladatnál az SPC200 négy RECBIT bemenetét használtuk fel, azaz számú lehetséges bitkombinációval dolgozhattunk. Ez azt jelenti, hogy 16 NC mondat használható fel a teljes vezérlés leírására.
Viszont lehetõség van alprogram hívására, amelyben 15 NC rekord a vezérlésre és egy rekord a foprogramba való visszatéréshez használható fel. Az alprogramban lévõ utasításokat is rekord kiválasztásos módon hajtja végre az SPC, nem futtatja le az alprogramot és lép vissza a foprogramba, mint Start Stop üzemmódban, hanem nekünk kell ugyanazokat a bitkombinációkat beadnunk, mint a fõprogram esetében, hogy az alprogramban lévõ rekord feladatait végrehajtassuk. Gondoskodnunk kell a foprogramba való visszajutást segítõ M02 tartalmú NC rekordot leíró bitkombinációról is.

Lap tetejére

PLC-program

A programban szereplõ hivatkozások jelentése:

A programtörzs és mûködése:
P0- Indítást leíró program:
STEP 1
IF NOP
THEN LOAD V6
TO CP0 'X tengelyen lépésszámlálás
SET C0 'X lépés

LOAD V7
TO CP1 'Y tengelyen lépésszámlálás
SET C1 'Y lépés

LOAD V255
TO FW1 'WEB vezérelt memória szó

STEP 2
IF I1.2 'Netes vez. engedély
THEN SET P1 'X tengely vezérlése
SET P2 'Y tengely vezérlése
SET P3 'Megfogó
SET P4 'Z tengely
SET P5 'Nullpontba küldés
SET P6 'Megfogó 0 fokba forgatása
SET P7 'Alaphelyzet felvétel
LOAD V1
TO FW2 'Üzem jelzõ
ELSE RESET P1 'X tengely vezérlése
RESET P2 'Y tengely vezérlése
RESET P3 'Megfogó
RESET P4 'Z tengely
RESET P5 'Nullpontba küldés
RESET P6 'Megfogó 0 fokba forgatása
RESET P7 'Alaphelyzet felvétel
LOAD V0
TO FW2 'Üzem jelzõ
LOAD V255
TO FW1 'WEB vezérelt memória szó

IF NOP
THEN JMP TO 2

A könnyebb áttekinthetõség érdekében önálló részekre lett szétszedve a mûködtetést leíró program. A 0-s számú program feladata az Interneten keresztüli vezérlés indítása, engedélyezése, valamint az egyes számlálók beállítása, értékkel feltöltése.
A berendezés mûködtetése e megírt program alapján, kizárólag a Webes felületen keresztül lehetséges. Nem használunk semmilyen kezelõ elemet, amellyel vezérelni lehetne az egyes pneumatikus egységeket.
A Webes vezérlés lényege, hogy belsõ regisztereket (flag) használunk a PLC programozása során. A jelzõbitek értékeinek változásából információt kapunk a PLC be- és kimeneti állapotairól (rendszerfelügyelet), és tudjuk e jelzõbitek értékeit a webes felületen keresztül változtatni, ezzel a PLC mûködését befolyásolni (vezérlés).
A STEP1-ben az X tengely lépésszámláló elõválasztóját 6 értékkel, az Y tengelyét, pedig 7 értékkel töltjük fel. Ezen értékekkel egyértelmûen be tudjuk határolni a paletta munkaterét. A számlálók aktuális értékét, pedig ki tudjuk olvasni a PLC memóriájából, és meg is tudjuk jeleníteni a HTML oldalon (23. ábra). Így meg tudjuk mondani -anélkül hogy látnánk a berendezést- a megfogó, paletta feletti pontos helyzetét.
A berendezés meghatározott állapotainak leírására az FW1-es memória szó lett felhasználva. Az FW1 decimális értékétõl függõen fogja kiküldeni az SPC200 számára a RECBIT jelkombinációt a PLC. Minden rendszerindítás vagy újraindítás esetén a memória szót a használt értékektõl különbözõ értékûre (pl.:255) kell, hogy feltöltsük. Ha ezt nem tennénk meg, akkor a PLC memóriájában megõrzött FW1 értékéhez tartozó feladat végrehajtódna, mielõtt az Internetes vezérlést engedélyezõ nyomógomb benyomásával valamilyen feladat utasítást adnánk ki a webes felületen.
A STEP2 felel a szervopneumatikus palettázó berendezés mûködtetését leíró programok elindításáért. Az egyes programok (P1-7) csak az I1.2-es bemenetre kötött reteszelhetõ nyomógomb benyomásával érhetõk el, ellenkezõ esetben azok inaktívak maradnak.
FW2 memória szót használjuk fel az üzemállapot kijeleztetésére a HTML oldalon. Ha az „üzemengedélyezõ” gomb benyomott állapotban van az FW2 értéke 1, egyébként 0. A HTML oldalon ezen értékekhez rendeljük az „Üzemen kívül” (30. ábra) és az „Üzem alatt” (31. ábra) üzenetfeliratokat.

P1- X tengely vezérlését leíró program:
STEP 1
IF FW1 'WEB vezérelt memória szó
= V1 " X irányú mozgás +ba
THEN RESET O0.7 'CLK_A
INC CW0 "X lépésértéke 1-el no
JMP TO 2
IF FW1 'WEB vezérelt memória szó
= V3 " X irányú mozgás -ba
THEN RESET O0.7 'CLK_A
JMP TO 4

STEP 2
IF C0 'X lépés
THEN SET O0.0 'RECBIT1
RESET O0.4 'RECBIT2
RESET O0.5 'RECBIT3
RESET O0.6 'RECBIT4
LOAD V100
TO TP2
SET T2
LOAD V255
TO FW1 'WEB vezérelt memória szó
ELSE LOAD V255
TO FW1 'WEB vezérelt memória szó
JMP TO 1

STEP 3
IF N T2
THEN SET O0.7 'CLK_A
JMP TO 1

STEP 4
IF CW0
> V5
THEN LOAD V5
TO CW0
ELSE JMP TO 5

STEP 5
IF NOP
THEN SET O0.0 'RECBIT1
SET O0.4 'RECBIT2
RESET O0.5 'RECBIT3
RESET O0.6 'RECBIT4
DEC CW0 "X lépésértéke 1-el csökken
LOAD V100
TO TP3
SET T3
LOAD V255
TO FW1 'WEB vezérelt memória szó

STEP 6
IF N T3
THEN SET O0.7 'CLK_A
JMP TO 1

A PLC P1 programja a palettázó berendezés X tengelyét képviselõ dugattyúrúd nélküli munkahengerét kívánja mûködtetni. Ez csak úgy valósulhat meg, ha olyan bináris kódot küld az SPC200 RECBIT bemenetére, amelyhez az X tengely mûködését leíró NC rekord tartozik. Jelen esetben ezt az N001 és N003, azaz 1-es és 3-as sor valósítja meg. Az 1-es számú NC mondatban pozitív, míg a 3-asban negatív irányú elmozdulás parancs szerepel. A 6. és 18. táblázatnak [7.] megfelelõen adódik ezen NC sorok címzését megvalósító PLC kimenetek értékei, amely a 19. táblázatban is látható.

19. táblázat X tengely mûködését leíró bitkombináció

Tehát attól függõen, hogy melyik NC rekordot kívánjuk elõhívni, annak megfelelõ bináris kódot küldünk az SPC-nek. A kód beküldése után egy úgynevezett engedélyezõ jelet kell beadnunk az SPC200 CLK_A nevû bemenetére, hogy a bitkombináció elfogadásra kerüljön.
A PLC programja így a következõ lépésekbõl áll:
STEP1-ben az FW1 memória szó értékétõl függõen, ha az 1, akkor a STEP2-bõl a pozitív irányú elmozdulást leíró (N001) NC rekord elõhívását megvalósító bitkód kerül elküldésre és az X tengely lépésszámlálóját 1-el növeljük. Ha pedig FW1 értéke 3, akkor a negatív irányba történõ elmozdulást leíró NC mondat bitkódja kerül elküldésre a STEP4-bõl. Technológiai megfontolás alapján a PLC O0.7 kimenetét 0-ra állítjuk, azért hogyha elõzõleg volt egy engedélyezõ jel kiadási parancs, akkor az mindenféleképpen törlésre kerüljön.
STEP2-ben pedig amíg van C0 jelünk, vagyis a számláló beállított értékét nem értük el, azaz a paletta határain belül vagyunk, beállítjuk a szükséges bitkombinációt a PLC kimenetén. A PLC megfelelõ kimeneti pontjai közvetlenül az SPC200 bemeneti pontjaira van kötve, ezáltal címzõdik meg a megfelelõ NC rekord. Az FW1 memória szó értékét egy nem használt értékre, 255-re változtatjuk. Ha ezt nem tesszük meg, akkor a STEP1-be visszatérve újra indul az egész folyamat és egy újabb lépéstávolságnyit halad az X tengely elõre, mert az FW1 értéke még mindig 1. Azonban mivel értékét felülírattuk, megáll és várakozik, míg értéke újra 1 nem lesz.
Ha volt C0 jelünk, akkor a STEP2-bõl a STEP3-ba lépünk, ahol az elõzõ lépésben beállított idõ lejárta után a bitkombináció elfogadtatását megvalósító CLK_A SPC200 bemenet kerül bekapcsolásra (PLC O0.7-es kimenete). A CLK_A jelének kiadása, vagy a számlálás lejárta után (C0 értéke 0 a STEP2-ben) a STEP1-re ugrunk vissza, az FW1 értékének vizsgálatához.
STEP4 a számláló további számolását küszöböli ki 5-nél nagyobb értékre léptetés esetén. Ez visszaszámlálásnál fontos, a paletta utolsó pontjából így 5-nél kezdi a leszámlálást, negatív irányú léptetés esetén.
STEP5 az N003 sorszámú NC rekordot címzõ, bitkombinációt meghatározó kimenetek, beállítását végzi el. FW1 értéke 255-re íródik, lépésszámlálót egyel csökkentjük és indítunk egy idõzítõt is, hogy megfelelõ idõ elteltével a STEP6-ban CLK_A engedélyezõ jel kiadásra kerüljön. Az eltelt idõre egy lényeges kikötés van -az SPC vezérlésébõl adódóan-, hogy nagyobbnak kell lennie, mint 10s.

P2- Y tengely vezérlését leíró program:
STEP 1
IF FW1 'WEB vezérelt memória szó
= V2 "Y irányú mozgás +ba
THEN RESET O0.7 'CLK_A
INC CW1 "Y lépésértéke 1-el nõ
JMP TO 2
IF FW1 'WEB vezérelt memória szó
= V4 "Y irányú mozgás -ba
THEN RESET O0.7 'CLK_A
JMP TO 4

STEP 2
IF C1 'Y lépés
THEN SET O0.4 'RECBIT2
RESET O0.0 'RECBIT1
RESET O0.5 'RECBIT3
RESET O0.6 'RECBIT4
LOAD V100
TO TP2
SET T2
LOAD V255
TO FW1 'WEB vezérelt memória szó
ELSE LOAD V255
TO FW1 'WEB vezérelt memória szó
JMP TO 1

STEP 3
IF N T2
THEN SET O0.7 'CLK_A
JMP TO 1

STEP 4
IF CW1
> V6
THEN LOAD V6
TO CW1
ELSE JMP TO 5

STEP 5
IF NOP
THEN SET O0.5 'RECBIT3
RESET O0.4 'RECBIT2
RESET O0.0 'RECBIT1
RESET O0.6 'RECBIT4
DEC CW1 "Y lépésértéke 1-el csökken
LOAD V100
TO TP3
SET T3
LOAD V255
TO FW1 'WEB vezérelt memória szó

STEP 6
IF N T3
THEN SET O0.7 'CLK_A
JMP TO 1

Az elv ugyanaz, mint az X tengely mûködtetésénél. Az Y tengely is egy dugattyúrúd nélküli munkahenger. A PLC bináris kódot küld az SPC200 RECBIT bemenetére, amelyhez az Y tengely mûködését leíró NC rekord tartozik, N002 és N004. A 2-es számú NC mondatban pozitív, míg a 3-asban negatív irányú elmozdulás parancs szerepel. A 20. táblázatnak megfelelõen kell a PLC kimeneti értékeit beállítani.

20. táblázat Y tengely mûködését leíró bitkombináció

FW1 memória szó értéke 2, akkor a pozitív irányú elmozdulást leíró N002 NC rekord elõhívását megvalósító bitkód kerül elküldésre, ha pedig 4, akkor a negatív irányba történõ elmozdulást leíró N004 NC mondat bitkódja kerül elküldésre.

P3- Megfogót muködteto program:
STEP 1
IF FW1 'WEB vezérelt memória szó
= V5 " Megfogó zár
THEN RESET O0.7 'CLK_A
JMP TO 2

IF FW1 'WEB vezérelt memória szó
= V7 " Megfogó nyit
THEN RESET O0.7 'CLK_A
JMP TO 6

STEP 2
IF NOP
THEN SET O0.0 'RECBIT1
SET O0.5 'RECBIT3
RESET O0.4 'RECBIT2
RESET O0.6 'RECBIT4
LOAD V30
TO TP2
SET T2
LOAD V255
TO FW1 'WEB vezérelt memória szó
STEP 3
IF N T2
THEN SET O0.7 'CLK_A
LOAD V30
TO TP3
SET T3

STEP 4
IF N T3
THEN SET O0.5 'RECBIT3
SET O0.4 'RECBIT2
RESET O0.0 'RECBIT1
RESET O0.6 'RECBIT4
RESET O0.7 'CLK_A
LOAD V30
TO TP4
SET T4

STEP 5
IF N T4
THEN SET O0.7 'CLK_A
JMP TO 1

STEP 6 "megfogó nyit
IF NOP
THEN SET O0.0 'RECBIT1
SET O0.5 'RECBIT3
SET O0.4 'RECBIT2
RESET O0.6 'RECBIT4
LOAD V30
TO TP2
SET T2
LOAD V255
TO FW1 'WEB vezérelt memória szó

STEP 7
IF N T2
THEN SET O0.7 'CLK_A
LOAD V30
TO TP3
SET T3

STEP 8
IF N T3
THEN RESET O0.5 'RECBIT3
RESET O0.4 'RECBIT2
RESET O0.0 'RECBIT1
SET O0.6 'RECBIT4
RESET O0.7 'CLK_A
LOAD V30
TO TP4
SET T4

STEP 9
IF N T4
THEN SET O0.7 'CLK_A
JMP TO 1

A Z tengelyen lévõ rakománymegfogó mûködtetése a cél a P3-as programban. A mûködtetést tekintve az FW1 flag értéke, ha 5, akkor a megfogónak zárnia kell, ha pedig 7, akkor nyitódnia.
Az egész folyamat leírásához kettõ-kettõ NC rekordot használunk fel, azaz négy különbözõ RECBIT bináris kódra van szükség. Ugyanis az N005 mondatban beállítjuk a megfogó zárt állapotát muködtetõ szelep jelét, az N006 rekordban pedig levesszük a gerjesztõ jelet (Set, Reset). Ugyanígy a megfogó nyitását végzõ szelepnek is két NC mondata van. N007 a beállítást, míg N008 a jel törlését valósítja meg.
STEP2-3 „Megfogó zár” NC mondathoz tartozó bitkombináció kiadása és elfogadtatása.
STEP4-5 Beállított idõ elteltével a „Megfogó zár” jelének elvételéhez tartozó NC mondat bitkódjának beíratása és elfogadtatása.
STEP6-7 „Megfogó nyit” NC mondathoz tartozó bitkombináció beállítása, elfogadtatása. STEP8-9 Beállított idõ elteltével „Megfogó nyit” jelének elvételéhez tartozó NC mondat bitkódjának beíratása és nyugtázása.

P4- Z tengely vezérlését leíró program:
STEP 1
IF FW1 'WEB vezérelt memória szó
= V9 " Z tengely felfelé
THEN RESET O0.7 'CLK_A
JMP TO 2

IF FW1 'WEB vezérelt memória szó
= V11 " Z tengely lefelé
THEN RESET O0.7 'CLK_A
JMP TO 6

STEP 2
IF NOP
THEN SET O0.0 'RECBIT1
SET O0.6 'RECBIT4
RESET O0.4 'RECBIT2
RESET O0.5 'RECBIT3
LOAD V50
TO TP2
SET T2
LOAD V255
TO FW1 'WEB vezérelt memória szó

STEP 3
IF N T2
THEN SET O0.7 'CLK_A
LOAD V50
TO TP3
SET T3

STEP 4
IF N T3
THEN SET O0.6 'RECBIT4
SET O0.4 'RECBIT2
RESET O0.5 'RECBIT3
RESET O0.0 'RECBIT1
RESET O0.7 'CLK_A
LOAD V50
TO TP4
SET T4

STEP 5
IF N T4
THEN SET O0.7 'CLK_A
JMP TO 1

STEP 6 "Z tengely lefelé
IF NOP
THEN SET O0.0 'RECBIT1
SET O0.6 'RECBIT4
SET O0.4 'RECBIT2
RESET O0.5 'RECBIT3
LOAD V40
TO TP2
SET T2
LOAD V255
TO FW1 'WEB vezérelt memória szó

STEP 7
IF N T2
THEN SET O0.7 'CLK_A
LOAD V40
TO TP3
SET T3

STEP 8
IF N T3
THEN RESET O0.0 'RECBIT1
RESET O0.4 'RECBIT2
SET O0.5 'RECBIT3
SET O0.6 'RECBIT4
RESET O0.7 'CLK_A
LOAD V30
TO TP4
SET T4

STEP 9
IF N T4
THEN SET O0.7 'CLK_A
JMP TO 1

Ugyanúgy, mint a megfogó esetén, két-két NC rekord írja le a mûködést Z tengelyre is, ugyanis a Z tengely egy egyszerû két véghelyzettel rendelkezõ, kettõs mûködtetésû dugattyúrúddal ellátott munkahenger.
A munkahenger a felsõ véghelyzetébe megy, ha FW1 értéke 9. Alsó véghelyzetbe pedig, 11 decimális érték esetén kerül.

P5- Nullpontfelvételt leíró program:
STEP 1
IF FW1 'WEB vezérelt memória szó
= V0 " Nullpontba küldés
THEN RESET O0.7 'CLK_A
LOAD V0 "X lépés szám visszaállítása
TO CW0
TO CW1
JMP TO 2
STEP 2
IF NOP
THEN RESET O0.4 'RECBIT2
RESET O0.0 'RECBIT1
RESET O0.5 'RECBIT3
RESET O0.6 'RECBIT4
LOAD V100
TO TP2
SET T2
LOAD V255
TO FW1 'WEB vezérelt memória szó

STEP 3
IF N T2
THEN SET O0.7 'CLK_A
JMP TO 1

Ha az FW1 memória szó értéke 0, akkor egy olyan NC mondat kerül megcímzésre (N000), amelynek feladata a tengelyek nullpontra állítása, azaz az X és az Y tengely is a (0,0) koordinátára mozog.
A tengelyek lépésszámlálóit egyértelmû, hogy ebben az esetben nulláznunk kell (LOAD V0 TO CW0 TO CW1).

P6- Megfogó - ba forgatását leíró program:
"Csak a megfogó alaphelyzetének visszaállítására szolgál

STEP 1
IF FW1 'WEB vezérelt memória szó
= V13 " Megfogó forgatás 0'ra
THEN RESET O0.7 'CLK_A
JMP TO 2

STEP 2
IF NOP
THEN SET O0.0 'RECBIT1
SET O0.5 'RECBIT3
RESET O0.4 'RECBIT2
SET O0.6 'RECBIT4
LOAD V30
TO TP2
SET T2
LOAD V255
TO FW1 'WEB vezérelt memória szó

STEP 3
IF N T2
THEN SET O0.7 'CLK_A
LOAD V30
TO TP3
SET T3

STEP 4
IF N T3
THEN SET O0.5 'RECBIT3
SET O0.4 'RECBIT2
RESET O0.0 'RECBIT1
SET O0.6 'RECBIT4
RESET O0.7 'CLK_A
LOAD V30
TO TP4
SET T4
STEP 5
IF N T4
THEN SET O0.7 'CLK_A
JMP TO 1

A berendezés mûködtetése közben többször is elõfordult a megfogóval, amiért nem volt egy meghatározott pozícióban tartva, hogy elfordult. Ezért került megírásra egy olyan sor az NC programban, amely azt a célt szolgálja, hogy a megfogót alaphelyzetbe, vagyis - ba fordítsa. Az FW1 értéke ebben az esetben 13-nak kell lennie.

P7- Alaphelyzet felvételt leíró program:
STEP 1
IF FW1 'WEB vezérelt memória szó
= V14 "Alaphelyzet felvétel
THEN RESET O0.7 'CLK_A
LOAD V0 "X lépésszám visszaállítása
TO CW0
TO CW1
STEP 2 "Megfogó nyit
IF NOP
THEN SET O0.0 'RECBIT1
SET O0.5 'RECBIT3
SET O0.4 'RECBIT2
RESET O0.6 'RECBIT4
LOAD V30
TO TP2
SET T2
LOAD V255
TO FW1 'WEB vezérelt memória szó
STEP 3
IF N T2
THEN SET O0.7 'CLK_A
LOAD V30
TO TP3
SET T3
STEP 4 "Megfogó nyit reset
IF N T3
THEN RESET O0.5 'RECBIT3
RESET O0.4 'RECBIT2
RESET O0.0 'RECBIT1
SET O0.6 'RECBIT4
RESET O0.7 'CLK_A
LOAD V30
TO TP4
SET T4

STEP 5
IF N T4
THEN SET O0.7 'CLK_A
LOAD V30
TO TP9
SET T9

STEP 6 "Z tengely fel
IF N T9
THEN SET O0.0 'RECBIT1
SET O0.6 'RECBIT4
RESET O0.4 'RECBIT2
RESET O0.5 'RECBIT3
RESET O0.7 'CLK_A
LOAD V30
TO TP5
SET T5

STEP 7
IF N T5
THEN SET O0.7 'CLK_A
LOAD V50
TO TP6
SET T6

STEP 8 "Z tengely fel reset
IF N T6
THEN SET O0.6 'RECBIT4
SET O0.4 'RECBIT2
RESET O0.5 'RECBIT3
RESET O0.0 'RECBIT1
RESET O0.7 'CLK_A
LOAD V50
TO TP7
SET T7

STEP 9
IF N T7
THEN SET O0.7 'CLK_A
LOAD V30
TO TP10
SET T10

STEP 10 "Nullpontba küldés
IF N T10
THEN RESET O0.4 'RECBIT2
RESET O0.0 'RECBIT1
RESET O0.5 'RECBIT3
RESET O0.6 'RECBIT4
RESET O0.7 'CLK_A
LOAD V50
TO TP8
SET T8

STEP 11
IF N T8
THEN SET O0.7 'CLK_A
JMP TO 1

A P7 programban egy teljes mûködési ciklus lett meghatározva. Ha az FW1 értéke 14, akkor a palettázó berendezésnek alaphelyzetbe kell kerülnie. Az eddig megírt programokat felhasználva, a folyamat lépései:

A program egyes részei a megfelelõ bitkombinációk és a nyugtázó jel kiadásáról szól. Azért, hogy az egyes lépések ténylegesen és láthatóan is egymás után induljanak, idõzítõk beiktatása történt. Mivel nullpontra küldés is történt, ezért a lépésszámlálók nullázása is végrehajtódik.

Lap tetejére

Nyitólap | Letöltés | Képek | Videók | WebDemo | Kapcsolat

Internet | TCP/IP | Rétegek | Világháló | HTML | PLC | FEC | Servo | Palettázó | Web felület | Összegzés | Irodalom

© NaZsi